{
    config,
    inputs,
    lib,
    pkgs,
    ...
}: let
    cfg = config.poz.services.greetd;
    inherit (config.poz.other.system) username;

    inherit (lib.meta) getExe getExe';
    inherit (lib.modules) mkIf;
    inherit (lib.options) mkEnableOption mkOption;
    inherit (lib.strings) concatStringsSep;
    inherit (lib.types) listOf str;

    inherit (inputs.hyprland.packages.${pkgs.system}) hyprland;

    hyprctl = getExe' hyprland "hyprctl";
    Hyprland = getExe' hyprland "Hyprland";

    greeter = getExe pkgs.greetd.${cfg.greeter};

    hyprlandConfig = pkgs.writeText "greetd-hyprland-config" ''
        misc {
            force_default_wallpaper=0
            focus_on_activate=1
        }

        animations {
            enabled=0
            first_launch_animation=0
        }

        workspace=1,default:true,gapsout:0,gapsin:0,border:false,decorate:false

        exec-once=[workspace 1;fullscreen;noanim] ${greeter} -l; ${hyprctl} dispatch exit
        exec-once=${hyprctl} dispatch focuswindow ${cfg.greeter}
    '';
in {
    options.poz.services.greetd = {
        enable = mkEnableOption "greetd";
        greeter = mkOption {
            description = "greetd frontend to use";
            type = str;
        };
        launchOptions = mkOption {
            description = "/etc/greetd/environments as list of strings";
            type = listOf str;
        };
    };

    config = mkIf cfg.enable {
        services.greetd = {
            enable = true;
            settings.default_session = {
                command = "${Hyprland} --config ${hyprlandConfig}";
                user = username;
            };
        };

        environment.etc."greetd/environments".text = concatStringsSep "\n" cfg.launchOptions;
    };
}