{
  lib,
  stdenv,
  fetchFromGitHub,
  cmake,
  python3,
  xorg,
  shadows ? false,
}:
stdenv.mkDerivation rec {
  pname = "winxp-cursors";
  version = "2023-11-22";

  src = fetchFromGitHub {
    owner = "rozniak";
    repo = "xfce-winxp-tc";
    fetchSubmodules = true;
    rev = "82243191359060a3c3c9e168e0e10fe2114caca3";
    hash = "sha256-bvkoe/L9KjMcCj5SlcNGoZKZtQwZHGYPFVSZbRfLztY=";
  };

  nativeBuildInputs = [cmake python3 xorg.xcursorgen];
  dontUseCmakeConfigure = true;

  cursor_variant =
    if shadows
    then "with-shadow"
    else "no-shadow";

  buildPhase = ''
    cd packaging
    mkdir -p build
    cd build
    cmake ../../cursors/${cursor_variant}/standard -DWINTC_SKU=""
    make
  '';

  installPhase = ''
    mkdir -p $out/share/icons/winxp-cursors/cursors/res
    cp -a xdg-compiled-maps/* $out/share/icons/winxp-cursors/cursors/
    cp compiled-cursors/* $out/share/icons/winxp-cursors/cursors/res/
    cp ../../cursors/${cursor_variant}/standard/index.theme $out/share/icons/winxp-cursors/
  '';

  meta = with lib; {
    description = "Windows XP Cursors";
    homepage = "https://github.com/rozniak/xfce-winxp-tc";
    license = with licenses; [unfreeRedistributable gpl2Plus];
    platforms = platforms.linux;
  };
}