nix/pkgs/default.nix

{ inputs, pkgs, ... }: with pkgs; [
  (final: prevPkgs: {
    win7-cursors = callPackage ./win7-cursors.nix {};
    sddm-i3-theme = callPackage ./sddm-i3-theme.nix {};
    ericw-tools-latest = callPackage ./ericw-tools-latest.nix {};
    godot4-mono = callPackage ./godot4-mono.nix {};
    alacritty-sixel = callPackage ./alacritty-sixel.nix {};
    i3status = prevPkgs.i3status.overrideAttrs (_: { patches = [ ../files/i3status-format-fix.patch ]; });
    flameshot = prevPkgs.flameshot.overrideAttrs (_: { patches = [ ../files/flameshot-0x0-upload.patch ]; });
    schildichat-web = callPackage ./schildi/schildichat-web.nix {};
    schildichat-desktop = callPackage ./schildi/schildichat-desktop.nix {};
    vkquake = prevPkgs.vkquake.overrideAttrs (prev: {
      version = "1.31.1";
      src = pkgs.fetchFromGitHub {
        inherit (prev.src) owner repo;
        rev = "38a9771d56cd2427c44724a2655b95281e29ba2d";
        sha256 = "sha256-rOzQMeSmnHZl4v0uWWqwp1yfnUqIuP18ogRn4DimKt4=";
      };
      sourceRoot = null;
      buildInputs = prev.buildInputs ++ [ pkgs.vulkan-headers ];
      nativeBuildInputs = prev.nativeBuildInputs ++ [ pkgs.glslang ];
      buildPhase = ''
        cd ../Quake
        make -j6 DO_USERDIRS=1 prefix=$out bindir=$out/bin
      '';
    });
    protontricks = prevPkgs.protontricks.overrideAttrs (prev: {
      src = pkgs.fetchFromGitHub {
        inherit (prev.src) owner repo;
        rev = "f7b1fa33b0438dbd72f7222703f8442e40edc510";
        sha256 = "sha256-t794WEMJx/JNX3gTMHfgquFWB7yXkleW07+QURm1NPM=";
      };
    });
    zed-editor = (inputs.zed.packages.${system}.zed-editor.overrideAttrs {
      patches = [
        ../files/zed-no-rounded-corners.patch
        ../files/zed-replace-window.patch
      ];
    });
  })
]