niksos/modules/services/greetd.nix

{
    config,
    inputs,
    lib,
    pkgs,
    ...
}: with lib; let 
    cfg = config.myOptions.services.greetd;
    username = config.myOptions.other.system.username;

    hyprlandConfig = pkgs.writeText "greetd-hyprland-config" ''
        misc {
            force_default_wallpaper=0
            focus_on_activate=1
        }

        animations {
            enabled=0
            first_launch_animation=0
        }

        workspace=1,default:true,gapsout:0,gapsin:0,border:false,decorate:false

        ${if config.myOptions.programs.waybar.enable  then "exec-once=systemctl --user stop waybar.service" else ""}
        exec-once=[workspace 1;fullscreen;noanim] ${pkgs.greetd.${cfg.greeter}}/bin/${cfg.greeter} -l; ${inputs.hyprland.packages.${pkgs.system}.hyprland}/bin/hyprctl dispatch exit
        exec-once=${inputs.hyprland.packages.${pkgs.system}.hyprland}/bin/hyprctl dispatch focuswindow ${cfg.greeter}
    '';
in {
    options.myOptions.services.greetd = {
        enable = mkEnableOption "enable greetd";
        greeter = mkOption {
            description = "greetd frontend to use";
            type = types.str;
        };
        launchOptions = mkOption {
            description = "/etc/greetd/environments as list of strings";
            type = with types; listOf str;
        };
    };

    config = mkIf cfg.enable {
        services.greetd = {
            enable = true;
            settings.default_session = {
                command = "${inputs.hyprland.packages.${pkgs.system}.hyprland}/bin/Hyprland --config ${hyprlandConfig}";
                user = username;
            };
        };

        environment.etc."greetd/environments".text = concatStringsSep "\n" cfg.launchOptions;
    };
}